Arduino - Expansão dinâmica de portas

Vaja como fazer para o Arduino identificar a quantidade de expansores (74hc595, max7219, etc) conectados em série. veja o vídeo.

vídeo anterior sobre o 74HC595:
http://youtu.be/SwQECcYdEkI

Link para o artigo:
http://www.arduinoecia.com.br/2014/04/Painel-de-led-max7219.html


código:

int conta_modulos(int pino, float Rb, float Rp){
  float La = analogRead(pino);
  double N = ( 1 / (  ((1023*Rb)/La) - Rb ) )  / ( 1 / Rp );
  int n = round(N);
    
  Serial.print(N);
  Serial.print(" arredondado: ");
  Serial.println(n);
  
  return n;
}

void setup() { Serial.begin(9600); }

void loop() {
  int q1 = conta_modulos(A0, 1000, 10000);  //resistor gnd->1K, resistor paralelo 10k
  delay(1000);
}

Arduino - Classe para 74HC595

No vídeo abaixo mostro como criar uma classe para facilitar o uso do Registrador 74HC595 com o Arduino.

Código:

ATENÇÃO:

o código abaixo foi melhorado, e publicado em um novo post. Clique aqui para o código atualizado.

class Expansor74HC595 {
  private:
    int  _pin_clock;
    int  _pin_latch;
    int  _pin_data;
    int  _num_cis;
    int* _pins;
    int  _envio_automatico;
  public:
    Expansor74HC595(int pin_clock, int pin_latch, int pin_data, int num_cis=1);
    void startWrite()         { _envio_automatico = false; };
    int  get_num_portas() { return _num_cis * 8; };
    void limpar() { for (int i=0;i < _num_cis * 8;i++){ _pins[i] = LOW; } enviar();  };
    int  read(int pin)  { if (pin >= get_num_portas()) {return LOW;} return _pins[pin]; };
  
    void enviar();
    void writeByte(int num_ci, byte values, bool q0=true);
    void write(int pin, int value);
};

Expansor74HC595::Expansor74HC595(int pin_clock, int pin_latch, int pin_data, int num_cis){
  _pin_clock        = pin_clock;
  _pin_latch        = pin_latch;
  _pin_data         = pin_data;
  _num_cis          = num_cis;
  _envio_automatico = true;
  _pins             = new int[_num_cis*8];
  
  pinMode(_pin_clock,OUTPUT);
  pinMode(_pin_latch,OUTPUT);
  pinMode(_pin_data, OUTPUT);
  limpar();
}

void Expansor74HC595::writeByte(int num_ci, byte b, bool q0) { 
  for(int i=(num_ci*8-1),j=q0?7:0;  i>=(num_ci-1)*8;  i--, q0?j--:j++) {
    _pins[i]  = (b & (1 << j)) ?  HIGH  :  LOW;
  }     
  
  if (_envio_automatico) { enviar(); }
}

void Expansor74HC595::write(int pin, int value) {
  if (pin >= get_num_portas()) {return;}
  _pins[pin] = value ? HIGH : LOW;
  if (_envio_automatico) { enviar(); }
}

void Expansor74HC595::enviar(){
  digitalWrite(_pin_latch, LOW); 
  
  for (int i=(_num_cis*8-1); i>=0; i-- ) {  
    digitalWrite(_pin_clock, LOW); 
    digitalWrite(_pin_data,  _pins[i]);
    digitalWrite(_pin_clock, HIGH); 
    digitalWrite(_pin_data,  LOW);
  }
  
  digitalWrite(_pin_latch,HIGH);
  
  _envio_automatico = true;
}


/*----------------------*/



const int PIN_CLOCK = 2; 
const int PIN_LATCH = 3; 
const int PIN_DATA  = 4; 

Expansor74HC595 *exp1;
 
void setup() {
  exp1 = new Expansor74HC595(PIN_CLOCK, PIN_LATCH, PIN_DATA, 16);
  
  Serial.begin(9600);
}


void conta_tempo(void(*p)(), String descricao){
  long m1, m2;
  m1 = millis();
  (*p)(); //executa a função
  m2 = millis();
 
  Serial.print(descricao + ": m1= ");
  Serial.print(m1);
  Serial.print(" - m2 = ");
  Serial.print(m2);
  Serial.print(" - dif = ");
  Serial.print(m2 - m1);
  Serial.println(" milissegundos");
}

void enviar(){
  exp1->enviar();
}
 
void loop() {
  
  for (int i=0; i<=255; i++) {                    //i=0-> B00000000   i=255-> B11111111
    exp1->startWrite();
    
    exp1->writeByte(1, i);         //q0 será o menos significativo   
    exp1->writeByte(3, i, false);  //q7 será o menos significativo
    
    exp1->write(8, 1); 
    exp1->write(9, 0);
    exp1->write(10, 1);
    exp1->write(11, 0);

    conta_tempo(enviar, "teste");

    //exp1->enviar();
  
    delay(500);
  
    exp1->startWrite();

    exp1->write(8, 0);
    exp1->write(9, 1);
    exp1->write(10, 0);
    exp1->write(11, 1);

    exp1->enviar();
    
    delay(500);  
    
    exp1->limpar();
    delay(300);    
  }
}

Arduino - Dicas de Programação 06 - tempo de processamento

Exemplo de como contar o tempo de processamento de um determinado procedimento.

código:

void setup() {
  Serial.begin(9600);
  pinMode(3, OUTPUT);
}

void conta_tempo(void(*p)(), String descricao){
  long m1, m2;

  m1 = millis();
  
  (*p)(); //executa a função
  
  m2 = millis();
 
  Serial.print(descricao + ": m1= ");
  Serial.print(m1);
  Serial.print(" - m2 = ");
  Serial.print(m2);
  Serial.print(" - dif = ");
  Serial.print(m2 - m1);
  Serial.println(" milissegundos");
}

void proc_01(){ for (long i=0; i< 10000; i++) { digitalWrite(3, !digitalRead(3)); } } 
void proc_02(){ for (long i=0; i< 30000; i++) { digitalWrite(3, !digitalRead(3)); } } 
void proc_03(){ for (long i=0; i< 100000; i++){ digitalWrite(3, !digitalRead(3)); } } 

void loop() {
  
  conta_tempo(proc_01, "proc 01");
  conta_tempo(proc_02, "proc 02");
  conta_tempo(proc_03, "proc 03");
  
  //proc_01();
  //proc_02();
  //proc_03();
}

Arduino - Lâmpadas - Parte 02

Continuando então com o tutorial de como ligar uma lâmpada, estou postando mais dois vídeos sobre o assunto e mais abaixo o código fonte do exemplo.

Circuito montado e funcionando

código fonte:

#include <EEPROM.h>


//inicio da Classe Lampada

class Lampada {
  private:
    //atributos
    int _pin_rele;
    int _pin_sensor_tensao;
    int _pin_sensor_corrente;
    int _address_eeprom;
    String _descricao;
    
    //metodos privados
    int  _le_eeprom();
    void _grava_eeprom();
    int _tem_tensao();
    int _tem_corrente();
  public:
    Lampada(int pin_rele, 
            int pin_sensor_tensao, 
            int pin_sensor_corrente, 
            int address_eeprom);
    
    void   ligar();
    void   desligar();
    void   inverter();
    
    int    esta_ligada();
    int    esta_danificada();
    void   set_descricao(String descricao);
    String get_descricao();
    String to_string();
};

Lampada::Lampada(int pin_rele, int pin_sensor_tensao, 
                 int pin_sensor_corrente, int address_eeprom) {  
  _pin_rele            = pin_rele;
  _pin_sensor_tensao   = pin_sensor_tensao;
  _pin_sensor_corrente = pin_sensor_corrente;
  _address_eeprom      = address_eeprom;
  
  pinMode(_pin_rele, OUTPUT);
  
  //quando o pino for menor ou igual a zero, significa que não será usado sensor de tensão
  if (_pin_sensor_tensao > 0)   { pinMode(_pin_sensor_tensao,   INPUT); }  
  

  //quando o pino for menor ou igual a zero, significa que não há sensor de corrente

  if (_pin_sensor_corrente > 0) { pinMode(_pin_sensor_corrente, INPUT); }  
  
  digitalWrite(_pin_rele, _le_eeprom() );
}

int  Lampada::_le_eeprom()    { return EEPROM.read(_address_eeprom);                   }

void Lampada::_grava_eeprom() { EEPROM.write(_address_eeprom, digitalRead(_pin_rele)); }

void Lampada::inverter()      { 
  digitalWrite(_pin_rele, !digitalRead(_pin_rele)); _grava_eeprom(); 
}

int  Lampada::_tem_corrente() { 
  if ( _pin_sensor_corrente <= 0 ) { return HIGH; } //caso não tenha sensor de corrente
  return digitalRead(_pin_sensor_corrente); 
}

int  Lampada::_tem_tensao()   { 
  //caso não tenha sensor de tensão
  if ( _pin_sensor_tensao <= 0 ) { return HIGH; }                                 

  for (int i=0;i<4;i++) {
    if (!digitalRead(_pin_sensor_tensao)) { return HIGH; }
    delay(1);
  }
  return LOW;
}

void Lampada::ligar()       { if (!esta_ligada())  { inverter(); } }
void Lampada::desligar()    { if (esta_ligada())   { inverter(); } }
int  Lampada::esta_ligada() { return ( _tem_tensao() && _tem_corrente() );  } 
int    Lampada::esta_danificada() { return ( _tem_tensao() && !_tem_corrente() ); }
String Lampada::get_descricao()   { return _descricao;                            }
void   Lampada::set_descricao(String descricao) { _descricao = descricao;         }

String Lampada::to_string(){
  String str = _descricao;
  if (esta_danificada()) {str += " - danificada."; return str;}
  str += esta_ligada() ? " - ligada." : " - desligada.";
  return str;
}

//fim da classe Lampada

const int PINO_RELE            = 8;
const int PINO_SENSOR_TENSAO   = 7;
const int PINO_SENSOR_CORRENTE = 6;
const int ADDRESS_EEPROM       = 0;

Lampada *lampada_01;

void setup() {
  Serial.begin(9600);

  lampada_01 = new Lampada(PINO_RELE, 
                           PINO_SENSOR_TENSAO, 
                           PINO_SENSOR_CORRENTE, 
                           ADDRESS_EEPROM);

  lampada_01->set_descricao("lampada 01");
}

void loop()  {
  char tecla = Serial.read();
  
  if (tecla == '1') {
    lampada_01->ligar();
  } else if (tecla == '2') {
    lampada_01->desligar();
  } else if (tecla  == '3') {
    lampada_01->inverter();
  }
  
  Serial.println(lampada_01->to_string());
   
}