Nesse fim de semana peguei uma impressora velha, uma HP Deskjet F4280 e tentei ver o que dava pra fazer com o display. Analisando os componentes que haviam na placa, identifiquei 3 registradores de deslocamento 595 - clique para ver o datasheet - (expansores de saídas) e 1 165 - clique para ver o datasheet - (expansor de entrada). Essa placa se comunicava com outra placa, através de um cabo flat através de 7 vias. Com ajuda de um multímetro identifiquei onde cada uma das vias estava chegando no circuito:
1 - pino 11 do 595 (SH_CP) e pino 2 do 165 (CLOCK)
2 - gnd
3 - pino 9 do 165 (QH)
4 - pino 14 do 595 (DS)
5 - vcc
6 - pino 12 do 595 (ST_CP) e pino 1 do 165 (LOAD)
7 - botão on/off - ligado diretamente
Com os pinos identificados, cortei com um tesoura um das extremidades do cabo flat e separei cada uma das trilhas. Com as pontas separadas, queimei o plástico que fica em volta do cabo flat para que apenas a trilha ficasse exposta, depois com um bombril removi os resíduos de plástico queimado dos terminais. Depois soldei essas trilhas em uma pequena placa, de modo que fosse possível conecta-las com o arduino através de jumpers.
--vou colocar uma foto de como foi feito
conforme as trilhas identificadas e numeradas acima, fiz a seguinte ligações no arduino:
1 --> arduino : pino 8
2 --> arduino : gnd
3 --> arduino : pino 2
4 --> arduino : pino 9
5 --> arduino : vcc
6 --> arduino : pino 10
7 --> arduino : não utilizado nesse exemplo. mas poderia ser ligado como qualquer pino e configura-lo como entrada
O próximo passo foi identificar como cada botão e cada led estavam sendo controlados. Os botões são controlados pelo único 165, e ao lado de cada botão (na cor preta) mostro qual o bit que é usado para representá-lo. Os outros 3 595 estão ligados em cascata, e têm suas saídas ligadas nos leds conforme numerados abaixo. O primeiro 595 está na cor Azul, o segundo na cor Vermelha e o terceira na Cor Verde.
Com tudo identificado, o próximo passo foi fazer a programação, pra isso aproveitei uma classe que eu já havia criado pra se comunicar com os registradores 595 e 165 juntos (veja o artigo aqui). Porém, o esquema desse display, não está exatamente da forma que mostrei no artigo citado, mas ainda assim deu pra aproveitar a classe, apenas fazendo algumas modificações. A principal delas, foi que quando é enviado HIGH para acionar um led, os leds são apagados.
Código-fonte:
/*
Criado em 27/09/2015
Por:
Fabiano A. Arndt
http://www.youtube.com/fabianoallex
http://fabianoallex.blogspot.com.br
fabianoallex@gmail.com
*/
/********************************************************************************************
*******************CLASSE Expansor74HC595_74HC165 INICIO*********************************
*********************************************************************************************/
class Expansor74HC595_74HC165 {
private:
int _pin_clock;
int _pin_latch;
int _pin_data;
byte* _pins_out;
byte* _pins_in;
int _num_cis_out;
int _num_cis_in;
public:
Expansor74HC595_74HC165(int pin_clock, int pin_latch, int pin_data, int num_cis_out, int num_cis_in){
_pin_clock = pin_clock;
_pin_latch = pin_latch;
_pin_data = pin_data;
_num_cis_out = num_cis_out;
_num_cis_in = num_cis_in;
_pins_out = new byte[num_cis_out];
_pins_in = new byte[num_cis_in];
pinMode(_pin_clock,OUTPUT);
pinMode(_pin_latch,OUTPUT);
clear();
}
void clear(){
for (int i=0; i<_num_cis_out; i++){ _pins_out[i] = B11111111; }
update();
}
void update(){
digitalWrite(_pin_clock, LOW);
digitalWrite(_pin_latch, LOW);
digitalWrite(_pin_latch, HIGH);
for(int i=max(_num_cis_in, _num_cis_out) * 8 - 1; i>=0; i-- ) { //max -->o for vai até o que tiver mais, ou entradas, ou saidas
int pos = i / 8;
int pin = 7-(i % 8);
if (i < _num_cis_in * 8){
pinMode(2, INPUT);
if ( digitalRead(2) ){
_pins_in[pos] |= (1 << pin); //set a bit HIGH
} else {
_pins_in[pos] &= ~(1 << pin); //set a bit LOW
}
}
if (i < _num_cis_out * 8){
pinMode(_pin_data, OUTPUT);
digitalWrite(_pin_data, (_pins_out[pos] & (1 << pin)) != 0 );
}
digitalWrite(_pin_clock, HIGH);
digitalWrite(_pin_clock, LOW);
}
digitalWrite(_pin_latch, LOW);
digitalWrite(_pin_latch, HIGH);
//pinMode(_pin_data, INPUT); //removido
}
int read(int pin){
int pos = pin / 8;
pin = 7-(pin % 8);
if (pos > _num_cis_out) {
pos = pos - _num_cis_out;
return ( (_pins_in[pos] & (1 << pin)) != 0 );
} else {
return ( (_pins_out[pos] & (1 << pin)) != 0 );
}
}
byte readByte(int num_ci) {
if (num_ci >= _num_cis_out) {
num_ci = num_ci - _num_cis_out;
return _pins_in[num_ci];
} else {
return _pins_out[num_ci];
}
}
void write(int pin, int value){
if (pin >= _num_cis_out*8) { return; }
int pos = pin / 8; //pos -> indica qual ci será atualizado.
pin = 7-(pin % 8);
if (pos > _num_cis_out) {
return; //se estiver tentando escrever um pino de entrada, apenas retorna, sem fazer nada.
} else {
if (value){
_pins_out[pos] |= (1 << pin); //set a bit HIGH
} else {
_pins_out[pos] &= ~(1 << pin); //set a bit LOW
}
}
}
void writeByte(int num_ci, byte b, int first = MSBFIRST) {
if (num_ci > _num_cis_out) {
return; //se estiver tentando escrever um pino de entrada, apenas retorna, sem fazer nada.
}
if (first == LSBFIRST) {
byte r=0;
for(int i=0;i<8;i++) {
r |= ((b>>i) & 0b1)<<(7-i);
}
b = r;
}
_pins_out[num_ci] = b;
} ;
};
/********************************************************************************************
*******************CLASSE Expansor74HC595_74HC165 FIM ***********************************
*********************************************************************************************/
const int PIN_CLOCK = 8;
const int PIN_LATCH = 10;
const int PIN_DATA_595 = 9;
const int PIN_DATA_165 = 2;
Expansor74HC595_74HC165 * exp1; //controla as saídas
Expansor74HC595_74HC165 * exp2; //controla as entradas
void setup() {
exp1 = new Expansor74HC595_74HC165(PIN_CLOCK, PIN_LATCH, PIN_DATA_595, 3, 0);
exp2 = new Expansor74HC595_74HC165(PIN_CLOCK, PIN_LATCH, PIN_DATA_165, 0, 3);
exp1->writeByte(0, B11111111);
exp1->writeByte(1, B11111111);
exp1->writeByte(2, B11111111);
Serial.begin(9600);
}
byte digitos[] = {
B01000000,
B01011110,
B00100100,
B00001100,
B00011010,
B10001000,
B10000000,
B01011100,
B00000000,
B00001000,
B00010000,
B10000010,
B11100000,
B00000110,
B10100000,
B10110000
};
byte leds[] = {20, 21, 22, 23, 4, 19, 18, 17, 16, 5};
unsigned int dig=0;
unsigned int opt=0;
unsigned int led=0;
void loop() {
exp2->update(); //primeiro verifica o estado dos botões
if (!exp2->read(5+16)) { exp1->write(15, !exp1->read(15)); }
if (!exp2->read(2+16)) { exp1->write(6, !exp1->read(6)); }
if (!exp2->read(0+16)) { dig++; }
if (!exp2->read(4+16)) { dig--; }
byte temp = exp1->read(15);
exp1->writeByte(1, digitos[dig%16]);
exp1->write(15, temp);
if (!exp2->read(6+16)) { opt++; }
exp1->write(1, opt%3+1==1);
exp1->write(2, opt%3+1==2);
exp1->write(3, opt%3+1==3);
if (!exp2->read(3+16)) {
for (int i=0; i<10; i++){
exp1->write(leds[i], led%10!=i);
}
led++;
}
exp1->update(); //agora envia o estado dos leds
Serial.println(exp1->readByte(0), BIN); //LE O PRIMEIRO CI (595)
Serial.println(exp1->readByte(1), BIN); //LE O SEGUNDO CI (595)
Serial.println(exp1->readByte(2), BIN); //LE O TERCEIRO CI (165)
Serial.println(exp2->readByte(2), BIN); //LE O QUARTO CI (165)
Serial.println("");
delay(100);
}
Como sabemos arrays são estruturas de dados utilizados para armazenar dados de um mesmo tipo em sequência. A sintaxe utilizada para a declaração de um array é a seguinte:
type nome_do_array [ tamanho ];
por exemplo,
int valores[10] = {1, 3, 2, 5, 6, 4, 8, 9, 7, 0};
É muito comum termos a necessidade de utilizarmos arrays para representar conjunto de dados como os listados acima.
Os tipos de dados a serem armazenados podem ser qualquer tipo de dado aceito em C.
boolean
char
unsigned char
byte
int
unsigned int
word
long
unsigned long
short
float
double
string - char array
String - object
Cada um dos tipos de dados tem um determinado tamanho que terá quer ser reservado na memória ao ser declarado um array. Um int, por exemplo, ocupa dois bytes de memória, um char ocupa um byte, um long ocupa 4 bytes.
Mas se tratando de programação para micro controladores, algo importante na hora de declarar um array, é escolhermos o tipo de dados mais adequado para armazenarmos os dados pretendidos. Por exemplo, se eu pretendo ter um array de números inteiros, mas os valores armazenados não ultrapassam o valor de 255, poderia utilizar um tipo de dados que não ocupasse mais de um byte, como word, ou byte. Caso contrário, teria que ser utilizado outro tipo, como int, ou ainda long. A escolha de cada um desses tipos de dados resulta em maiores ou menores quantidades de memória utilizadas. Em aplicações pequenas, talvez isso não faça diferença, mas algumas situações acaba fazendo.
Uma situação especial, e bastante comum, é necessitarmos armazenar arrays com informações binárias, ou seja, valor do tipo 1 ou 0. ou true ou false, ou HIGH ou LOW. enfim, apenas dois valores distintos podem ser armazenados em cada posição.
Um exemplo comum, seria por exemplo criar um array pra controlar o estado de um conjunto de lâmpadas, onde elas podem estar ou ligadas ou desligadas.
Vamos supor que fossem 20 lampadas.
Uma maneira fácil seria criar um array assim:
int lampadas[20] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};
Mas será que essa é a melhor forma de declarar esse array?
Como sabemos, int ocupa dois bytes. Multiplicado por 20, totalizaria 40 bytes.
Mas e se quisermos diminuir ainda mais? Nesse caso teríamos que ter um tipo de dados que ocupasse menos de um byte, mas isso infelizmente a linguagem C não nos oferece, mas ainda assim há um jeito de diminuirmos.
Como sabemos, 1 byte é formado por 8 bits. E cada bit pode assumir apenas dois estados, ou seja, 1 ou 0. Uma saída então, seria utilizar 1 byte, pra controlar 8 lâmpadas. Com isso precisaríamos ter 20 / 8 (2.5 --> 3) bytes para representar os estados das 20 lâmpadas. ou seja, algo assim:
byte lampadas[3]; //24 bits disponíveis
O que totalizaria apenas 3 bytes de memória para gerenciar o estado de 20 lâmpadas.
Sem dúvida essa é uma estratégia bem útil quando temos limitações de memória importante, o que é bem comum quando se trata de micro controladores.
Mas como tudo tem seu preço, teremos agora que criarmos meios de alterarmos bit a bit de cada um dos bytes e para isso precisaremos utilizar operadores de bitwise.
Já fiz um vídeo explicando como funcionam operadores de bitwise, quem não conhece, vale muito a pena aprender.
Pra facilitar o uso desses recursos, criei uma classe que encapsula toda essa parte "complicada", a qual está abaixo:
class BitArray{
private:
int _num_bits; //quantidade de bits a serem gerenciados
int _num_bytes; //quantidade de bytes utilizados para armazenar os bits a serem gerenciados
byte * _bytes; //array de bytes onde estaram armazenados os bits
public:
BitArray(int num_bits){
_num_bits = num_bits;
_num_bytes = _num_bits/8 + (_num_bits%8 ? 1 : 0) + 1;
_bytes = (byte *)(malloc( _num_bytes * sizeof(byte) ) );
}
void write(int index, byte value) {
byte b = _bytes[ index/8 + (index%8 ? 1 : 0) ];
unsigned int bit = index%8;
if (value) { b |= (1 << bit); } else { b &= ~(1 << bit); }
_bytes[ index/8 + (index%8 ? 1 : 0) ] = b;
}
void write(byte value) {
for(int j=0; j<_num_bytes;j++) { _bytes[j] = value ? B11111111 : B00000000; }
}
int read(int index) {
byte b = _bytes[ index/8 + (index%8 ? 1 : 0) ];
unsigned int bit = index%8;
return (b & (1 << bit)) != 0;
}
~BitArray(){ free( _bytes ); }
};
Com isso, agora não iremos ter um array, mas sim um objeto, o qual poderá ser utilizado da seguinte maneira:
BitArray lampadas(20); //instancia do objeto com 20 bits
E para alterarmos uma das lâmpadas, fazemos da seguinte maneira:
lampadas.write(0, HIGH); //liga a primeira lampada
lampadas.write(1, HIGH); //liga a segunda lampada
if ( lampadas.read(0) ) { Serial.println("a primeira lampada está ligada."); } //verifica o estado da lampada.
Com isso conseguimos ter o menor consumo de memória, sem termos grandes dificuldades na parte de programação.
versão bidimensional :
class BitArray2D {
private:
unsigned int _rows;
unsigned int _columns;
unsigned int _cols_array; //pra cada 8 colunas, 1 byte é usado
byte** _bits;
public:
BitArray2D(unsigned int rows, unsigned int columns){
_rows = rows;
_columns = columns;
_cols_array = columns/8 + (_columns%8 ? 1 : 0) + 1; //divide por 8 o número de colunas
_bits = (byte **)malloc(_rows * sizeof(byte *));
for(int i=0;i<_rows;i++){ _bits[i] = (byte *)malloc( _cols_array * sizeof(byte)); } //cria varios arrays
clear();
}
unsigned int rows(){ return _rows; }
unsigned int columns(){ return _columns; }
void clear() {
for(int i=0;i<_rows;i++){
for(int j=0; j<_cols_array;j++) { _bits[i][j] = B00000000; }
}
}
void write(unsigned int row, unsigned int column, int value){
byte b = _bits[row][ column/8 + (column%8 ? 1 : 0) ];
unsigned int bit = column%8;
if (value) { b |= (1 << bit); } else { b &= ~(1 << bit); }
_bits[row][ column/8 + (column%8 ? 1 : 0) ] = b;
}
void write(byte value){
for(int i=0;i<_rows;i++){
for(int j=0; j<_cols_array;j++) {
_bits[i][j] = value ? B11111111 : B00000000;
}
}
}
int read(unsigned int row, unsigned int column){
byte b = _bits[row][ column/8 + (column%8 ? 1 : 0) ];
unsigned int bit = column%8;
return (b & (1 << bit)) != 0;
}
void toggle(unsigned int row, unsigned int column){ write(row, column, !read(row, column)); }
void toggle(){ for(int i=0;i<_rows;i++){ for(int j=0; j<_columns;j++) { toggle(i,j); } } }
};
Algumas alterações feitas na biblioteca LedControl.
Quando usamos repetidamente o método setLed da biblioteca LedControl, percebemos um atraso na atualização dos displays (como pode ser visto no vídeo abaixo). Isso acontece, pois a cada chamada de setLed, é feito o envio do status de todos os leds do display, inclusive, os que não tiveram alterações, o que compromete muito a eficiência do código.
Para melhorar a performance da biblioteca foi incluída uma nova funcionalidade, a qual permite atualizar os status dos leds sem enviar os dados para os registradores de deslocamento (Max7219), ou seja, as alterações são mantidas na memória, e depois do processamento terminado, os dados são, então, enviados todos de uma única vez aos registradores. Essa funcionalidade se chama "Auto Send".
Por default a biblioteca funciona da mesma forma que é originalmente, com o auto send igual a true, ou seja, cada chamada a clear(), setLed(), setRow() ou setColumn() continua enviando os dados aos registradores. Mas caso o programador queira fazer um conjunto de alterações nos leds e só enviar as informações para os registradores após todas as alterações estarem prontas, deve-se então, usar o método startWrite().
Depois de chamado startWrite(), os dados serão alterados mas apenas na memória e só serão enviados aos registradores através de um outro método que foi criado. O método send().
No código-fonte a baixo, vemos o uso desses dois métodos, na função update_display. Como pode ser visto, antes de iniciar o processamento dos dados, é feita uma chamada a startWrite(), e ao final uma chamada a send().
void update_displays() {
lc.startWrite();
for (int lin=0; lin<8; lin++) {
for (int col=0; col<16; col++) {
for (int i=0; i<2; i++) {
int l = lin;
int c = col - (i*8);
if (l>=0 && l<=7 && c>=0 && c<=7) {
lc.setLed(i, l, c, (l+c+cont)%2 );
}
}
}
}
cont++;
lc.send();
}
Observações: No código abaixo, foram removidas as funcionalidades voltadas ao uso de displays de 7 segmentos, pois não serão utilizados nos meu projetos futuros, mas nada impede que sejam inclusos novamente.
Código-fonte:
/*************************************************************************************************************
*******************************LEDCONTROL ALTERADA************************************************************
**************************************************************************************************************/
//the opcodes for the MAX7221 and MAX7219
#define OP_DECODEMODE 9
#define OP_INTENSITY 10
#define OP_SCANLIMIT 11
#define OP_SHUTDOWN 12
#define OP_DISPLAYTEST 15
class LedControl {
private :
byte spidata[16];
byte * status;
int SPI_MOSI;
int SPI_CLK;
int SPI_CS;
int maxDevices;
int _auto_send;
void spiTransfer(int addr, volatile byte opcode, volatile byte data) {
int offset = addr*2;
int maxbytes = maxDevices*2;
for(int i=0;i<maxbytes;i++) { spidata[i]=(byte)0; }
spidata[offset+1] = opcode;
spidata[offset] = data;
digitalWrite(SPI_CS,LOW);
for(int i=maxbytes;i>0;i--) { shiftOut(SPI_MOSI,SPI_CLK,MSBFIRST,spidata[i-1]); }
digitalWrite(SPI_CS,HIGH);
}
public:
LedControl(int dataPin, int clkPin, int csPin, int numDevices) {
_auto_send = true;
SPI_MOSI = dataPin;
SPI_CLK = clkPin;
SPI_CS = csPin;
maxDevices = numDevices;
pinMode(SPI_MOSI, OUTPUT);
pinMode(SPI_CLK, OUTPUT);
pinMode(SPI_CS, OUTPUT);
digitalWrite(SPI_CS, HIGH);
status = new byte[maxDevices * 8]; //instancia o array de acordo com a quantia de displays usados
for(int i=0;i<maxDevices * 8 ;i++) { status[i]=0x00; }
for(int i=0;i<maxDevices;i++) {
spiTransfer(i, OP_DISPLAYTEST,0);
setScanLimit(i, 7); //scanlimit is set to max on startup
spiTransfer(i, OP_DECODEMODE,0); //decode is done in source
clearDisplay(i);
shutdown(i,true); //we go into shutdown-mode on startup
}
}
void startWrite() { _auto_send = false; };
void send() {
for (int j=0; j<maxDevices; j++) {
int offset = j*8;
for(int i=0;i<8;i++) { spiTransfer(j, i+1, status[offset+i]); }
}
_auto_send = true;
}
int getDeviceCount(){ return maxDevices; }
void shutdown(int addr, bool b){
if(addr<0 || addr>=maxDevices) return;
spiTransfer(addr, OP_SHUTDOWN, b ? 0 : 1);
}
void setScanLimit(int addr, int limit){
if(addr<0 || addr>=maxDevices) return;
if(limit>=0 && limit<8) spiTransfer(addr, OP_SCANLIMIT,limit);
}
void setIntensity(int addr, int intensity) {
if(addr<0 || addr>=maxDevices) { return; }
if(intensity>=0 && intensity<16) { spiTransfer(addr, OP_INTENSITY, intensity); }
}
void clearDisplay(int addr){
if(addr<0 || addr>=maxDevices) return;
int offset = addr*8;
for(int i=0;i<8;i++) {
status[offset+i] = 0;
if (_auto_send) { spiTransfer(addr, i+1, status[offset+i]); }
}
}
void setLed(int addr, int row, int column, boolean state) {
if(addr<0 || addr>=maxDevices) { return; }
if(row<0 || row>7 || column<0 || column>7) { return; }
int offset = addr*8;
byte val = B10000000 >> column;
if(state) { status[offset+row] = status[offset+row] | val; }
else {
val=~val;
status[offset+row] = status[offset+row]&val;
}
if (_auto_send) { spiTransfer(addr, row+1, status[offset+row]); }
}
void setRow(int addr, int row, byte value) {
if(addr<0 || addr>=maxDevices) return;
if(row<0 || row>7) return;
int offset = addr*8;
status[offset+row] = value;
if (_auto_send) {
spiTransfer(addr, row+1, status[offset+row]);
}
}
void setColumn(int addr, int col, byte value) {
if(addr<0 || addr>=maxDevices) return;
if(col<0 || col>7) return;
byte val;
for(int row=0; row<8; row++) {
val=value >> (7-row);
val=val & 0x01;
setLed(addr,row,col,val);
}
}
};
/*************************************************************************************************************
*******************************FIM LEDCONTROL ALTERADA********************************************************
**************************************************************************************************************/
/*
pin 4 is connected to the DataIn
pin 6 is connected to the CLK
pin 5 is connected to LOAD
*/
LedControl lc=LedControl(4,6,5,2);
const int LINHAS = 8;
const int COLUNAS = 16;
int cont=0;
void update_displays() {
lc.startWrite();
for (int lin=0; lin<8; lin++) {
for (int col=0; col<16; col++) {
for (int i=0; i<2; i++) {
int l = lin;
int c = col - (i*8);
if (l>=0 && l<=7 && c>=0 && c<=7) {
lc.setLed(i, l, c, (l+c+cont)%2 );
}
}
}
}
cont++;
lc.send();
}
void setup() {
lc.shutdown(0,false);
lc.setIntensity(0,8);
lc.clearDisplay(0);
lc.shutdown(1,false);
lc.setIntensity(1,8);
lc.clearDisplay(1);
Serial.begin(9600);
}
void loop() {
update_displays();
for(int i=0;i<LINHAS;i++){
for(int j=0;j<COLUNAS;j++){
Serial.print( (i+j)%2 );
Serial.print(" ");
}
Serial.println(" ");
}
Serial.println(" ");
delay(2000);
}
Arduino é uma plataforma de prototipação que fez sucesso devido a facilidade com que junta eletrônica e programação e apresenta aos interessados nessas áreas. Tanto pessoas com experiência como sem experiências podem começar a implementar seus projetos sem ter que se preocupar muito com os fundamentos dessas duas áreas de conhecimento. Claro que isso é bom, pois democratiza o conhecimento e permite com que ideias saiam do papel e se tornem projetos, sejam simples ou mais complexos, mas isso não significa que não devemos nos aprofundar nos conhecimentos dessas duas áreas de conhecimento.
A IDE padrão do Arduino, utiliza C/C++, e o que eu quero mostrar aqui são algumas pegadinhas em que as vezes programadores menos experientes podem cair.
C/C++ é uma linguagem Fortemente Tipada. Isso significa que sempre que formos declarar uma variável, precisamos definir a que tipo de dados ela pertence.
Os principais tipos de variáveis são:
void
boolean
char
unsigned char
byte
int
unsigned int
word
long
unsigned long
short
float
double
string - char array
String - object
array
Minha intenção não é apresentar e explicar os tipos de dados utilizados para programar o Arduino, mas mostrar alguns detalhes que devemos prestar atenção na hora de programar.
Se olharmos os tipos acimas, veremos que alguns deles, como int, char e long, possuem o tipo unsigned, por exemplo, tem int, e tem unsigned int.
Mas qual a diferença entre esses dois tipos? Para exemplificar vamos pegar os tipos int e unsigned int. Tanto um como outro irá reservar 16 bits de memória para cada variável declarada. A diferença é que int armazena números que vão de -32.768 a 32.767, ou seja, aceita números negativos. Enquanto que unsigned int, armazena números de 0 a 65.535.
Agora vamos imaginar o seguinte, iremos declarar duas variáveis, uma variável i do tipo int, e uma variável u do tipo unsigned int e inicializamos cada uma com o valor 0.
Se agora fizermos um if verificando se i é igual a u, obviamente o if será verdadeiro, pois ambas possuem valor 0.
Agora supomos que o valor das duas variáveis sejam decrementadas em 1 (i-- e u--). Vamos analisar então o que acontece com cada uma das variáveis.
Se i era igual a 0, agora ela será igual a -1. Já no caso de u, é diferente, pois u não pode armazenar valores negativos. Nesse caso, u-- var resultar no seguinte valor: 65.535. Isso mesmo. O valor assumido é o último valor dos possíveis valores para o tipo unsigned int. Isso sempre acontece quando extrapolamos os valores aceitos por esses tipos de dados, seja no início ou no fim.
Pois bem, considerando então que i é igual a -1 e u igual a 65.535, o que aconteceria se novamente verificássemos se i é igual a u. Apesar de não ser tão óbvio agora, a comparação continuaria resultado verdadeiro. Sim. -1 seria igual a 65.535.
O que acontece aqui é o seguinte: Quando uma comparação entre dois tipos é feita, é preciso que o compilador converta os tipos de dados para um mesmo tipo, e nessa conversão, os dados resultantes da conversão dos tipos de dados vão ser os mesmos, ou seja iguais. O que, dependendo da lógica que está sendo programada, pode levar a erros. E o programador menos experiente pode ficar doidinho tentando entender o que está acontecendo e não conseguir achar o problema.
Sketch com o exemplo acima
int i = 0; /* -32.768 .. 32.767 */
unsigned int u = 0; /* 0 .. 65.535 */
void setup() {
Serial.begin(9600);
}
void loop() {
Serial.print("i = ");
Serial.print(i);
Serial.println("");
Serial.print("u = ");
Serial.print(u);
Serial.println("");
if (i == u) {
Serial.println("iguais");
} else {
Serial.println("diferentes");
}
i--;
u--;
delay(5000);
Serial.println("");
Serial.println("");
}
Vamos imaginar agora um exemplo parecido, mas ao invés de decrementarmos as duas variaveis, vamos decrementar apenas i e iremos verificar se i é maior, menor ou igual a u.
int i = 0; /* -32.768 .. 32.767 */
unsigned int u = 0; /* 0 .. 65.535 */
void setup() {
Serial.begin(9600);
}
void loop() {
Serial.print("i = ");
Serial.print(i);
Serial.println("");
Serial.print("u = ");
Serial.print(u);
Serial.println("");
if (i == u) {
Serial.println("iguais");
} else {
if (i > u) {
Serial.println("i maior que u");
} else {
Serial.println("u maior que i");
}
}
i--; //apenas i é decrementado
delay(5000);
Serial.println("");
Serial.println("");
}
Veja que mesmo i sendo negativo, o programa entende que i é maior que zero. Isso acontece pelo mesmo motivo mostrado anteriormente. O compilador precisa converteri, que é int, em unsigned int. pois só pode comparar variáveis do mesmo tipo, e nessa conversão de um tipo para outro, o valor que era -1, passa a ser 65.535, ou seja, após a conversão, i de fato passa a ser maior que u.
Conclusão
Sempre que for declarar o tipo de dado, pense exatamente o que aquele dado vai representar, se de fato pode ou não haver valores negativos. E se haver, pense nos problemas que podem ocorrer. E procure não misturar os tipos de dados na hora de fazer comparações ou outras operações entre eles. E o principal: Sempre teste seu código com todas as possibilidades de valores.
Pra quem estiver interessado, vou deixar o código-fonte, mas já aviso, que foi algo rápido, sem muito planejamento, e que com certeza dá pra ser melhorado.
Uma das melhorias que poderiam ser feitas, é substituir os delays, pelos millis. Tenho um artigo falando sobre como fazer isso. veja aqui.
Outro detalhe é que utilizo uma classe que criei pra gerar números aleatórios não repetidos. Quem quiser saber mais detalhes sobre essa classe, veja o artigo, clicando aqui.
valeu!
código-fonte:
#include "LedControl.h"
/**********************************************************************************
************************************CLASSE UNIQUE RANDOM***************************
**********************************************************************************/
class UniqueRandom{
private:
int _index;
int _min;
int _max;
int _tam;
int* _list;
void _init(int min, int max) {
_list = 0;
if (min < max) { _min = min; _max = max; } else { _min = max; _max = min; }
_tam = _max - _min;
_index = 0;
}
public:
UniqueRandom(int max) { _init(0, max); randomize(); } //construtor com 1 parametro
UniqueRandom(int min, int max) { _init(min, max); randomize(); } //construtor com 2 parametros
void randomize() {
if (_list == 0) { _list = (int*) malloc(_tam * sizeof(int)); }
for (int i=0; i<_tam; i++) { _list[i] = _min+i; } //preenche a lista do menor ao maior valor
//embaralha a lista
for (int i=0; i<_tam; i++) {
int r = random(0, _tam); //sorteia uma posição qualquer
int aux = _list[i];
_list[i] = _list[r];
_list[r] = aux;
}
}
int next() { //retorna o proximo numero da lista
int n = _list[_index++];
if (_index >= _tam ) { _index = 0;} //após recuper o ultimo numero, recomeça na posicao 0
return n;
}
~UniqueRandom(){ free ( _list ); } //destrutor
};
/**********************************************************************************
************************************FIM CLASSE UNIQUE RANDOM***********************
**********************************************************************************/
/*
pin 4 is connected to the DataIn
pin 6 is connected to the CLK
pin 5 is connected to LOAD
*/
LedControl lc(4,6,5, 2); //2 max7219
UniqueRandom ur(64); //declaracao do objeto unique random
/* we always wait a bit between updates of the display */
unsigned long delaytime=500;
void setup() {
int seed = 0;
for (int i=0; i<10; i++) {
seed += ( analogRead(A0) + analogRead(A1) + analogRead(A2) + analogRead(A3) + analogRead(A4) + analogRead(A5) ) ;
delay(10);
}
randomSeed(seed);
lc.shutdown(0,false);
lc.setIntensity(0,1);
lc.clearDisplay(0);
lc.shutdown(1,false);
lc.setIntensity(1,1);
lc.clearDisplay(1);
int lin = 0;
lc.setColumn(1, lin++, B11111111);
lc.setColumn(1, lin++, B11111111);
lc.setColumn(1, lin++, B01110000);
lc.setColumn(1, lin++, B00111000);
lc.setColumn(1, lin++, B00011100);
lc.setColumn(1, lin++, B00001110);
lc.setColumn(1, lin++, B11111111);
lc.setColumn(1, lin++, B11111111);
delay(500);
}
byte leds_0[8] = {
B00111000,
B00111000,
B00011000,
B00011000,
B00011000,
B00011000,
B01111110,
B01111110
};
byte leds_1[8] = {
B11000011,
B11100011,
B11110011,
B11111011,
B11011111,
B11001111,
B11000111,
B11000011
};
void loop() {
int aleatorio = random(0, 9);
//aleatorio = 8;
Serial.println(aleatorio);
if (aleatorio == 0) {
//linhas de cima para baixo
lc.clearDisplay(0);
delay(delaytime/2);
for(int row=0;row<8;row++) { lc.setRow(0,row, leds_0[row]);delay(50); }
delay(delaytime*5);
}
if (aleatorio == 1) {
//linhas de baixo para cima
lc.clearDisplay(0);
delay(delaytime/2);
for(int row=7;row>=0;row--) { lc.setRow(0,row, leds_0[row]);delay(50); }
delay(delaytime*5);
}
if (aleatorio == 2) {
//direita para a esquerda
lc.clearDisplay(0);
delay(delaytime/2);
for (int col=0;col<8;col++){
for(int row=0;row<8;row++) { lc.setLed(0, row, col, (leds_0[row] & (1 << (7-col) )) != 0 ); }
delay(50);
}
delay(delaytime*5);
}
if (aleatorio == 3) {
//esquerda para a direita
lc.clearDisplay(0);
delay(delaytime/2);
for (int col=7;col>=0;col--){
for(int row=0;row<8;row++) { lc.setLed(0, row, col, (leds_0[row] & (1 << (7-col) )) != 0 ); }
delay(50);
}
delay(delaytime*5);
}
if (aleatorio == 4) {
//direita para a esquerda
lc.clearDisplay(0);
delay(delaytime/2);
for(int row=0;row<8;row++) {
for (int col=0;col<8;col++){
lc.setLed(0, row, col, (leds_0[row] & (1 << (7-col) )) != 0 );
if ( (leds_0[row] & (1 << (7-col) )) != 0 ) {
delay(100);
}
}
}
delay(delaytime*5);
}
if (aleatorio == 5) {
//direita para a esquerda
lc.clearDisplay(0);
delay(delaytime/2);
for(int row=0;row<8;row++) {
for (int col=7;col>=0;col--){
lc.setLed(0, row, col, (leds_0[row] & (1 << (7-col) )) != 0 );
if ( (leds_0[row] & (1 << (7-col) )) != 0 ) {
delay(100);
}
}
}
delay(delaytime*5);
}
if (aleatorio == 6) {
//------------------------
lc.clearDisplay(0);
delay(delaytime/2);
for (int col=0;col<8;col++){
for(int row=0;row<8;row++) {
lc.setLed(0, row, col, (leds_0[row] & (1 << (7-col) )) != 0 );
if ( (leds_0[row] & (1 << (7-col) )) != 0 ) {
delay(100);
}
}
}
delay(delaytime*5);
}
if (aleatorio == 7) {
//--------------------------
lc.clearDisplay(0);
delay(delaytime/2);
for (int col=7;col>=0;col--){
for(int row=0;row<8;row++) {
lc.setLed(0, row, col, (leds_0[row] & (1 << (7-col) )) != 0 );
if ( (leds_0[row] & (1 << (7-col) )) != 0 ) {
delay(100);
}
}
}
delay(delaytime*5);
}
if (aleatorio == 8) {
//--------------------------
lc.clearDisplay(0);
delay(delaytime/2);
for(int i=0;i<64;i++) {
int r = ur.next();
int l = r / 8;
int c = r % 8;
int val = (leds_0[l] & (1 << (7-c) )) != 0 ;
if ( val ) { delay(100); }
lc.setLed(0, l, c, val );
}
ur.randomize();
delay(delaytime*5);
}
aleatorio = random(0, 9);
if (aleatorio == 0) {
//linhas de cima para baixo
lc.clearDisplay(1);
delay(delaytime/2);
for(int row=0;row<8;row++) { lc.setRow(1,row, leds_1[row]);delay(50); }
delay(delaytime*5);
}
if (aleatorio == 1) {
//linhas de baixo para cima
lc.clearDisplay(1);
delay(delaytime/2);
for(int row=7;row>=0;row--) { lc.setRow(1,row, leds_1[row]);delay(50); }
delay(delaytime*5);
}
if (aleatorio == 2) {
//direita para a esquerda
lc.clearDisplay(1);
delay(delaytime/2);
for (int col=0;col<8;col++){
for(int row=0;row<8;row++) { lc.setLed(1, row, col, (leds_1[row] & (1 << (7-col) )) != 0 ); }
delay(50);
}
delay(delaytime*5);
}
if (aleatorio == 3) {
//esquerda para a direita
lc.clearDisplay(1);
delay(delaytime/2);
for (int col=7;col>=0;col--){
for(int row=0;row<8;row++) { lc.setLed(1, row, col, (leds_1[row] & (1 << (7-col) )) != 0 ); }
delay(50);
}
delay(delaytime*5);
}
if (aleatorio == 4) {
//direita para a esquerda
lc.clearDisplay(1);
delay(delaytime/2);
for(int row=0;row<8;row++) {
for (int col=0;col<8;col++){
lc.setLed(1, row, col, (leds_1[row] & (1 << (7-col) )) != 0 );
if ( (leds_1[row] & (1 << (7-col) )) != 0 ) {
delay(100);
}
}
}
delay(delaytime*5);
}
if (aleatorio == 5) {
//direita para a esquerda
lc.clearDisplay(1);
delay(delaytime/2);
for(int row=0;row<8;row++) {
for (int col=7;col>=0;col--){
lc.setLed(1, row, col, (leds_1[row] & (1 << (7-col) )) != 0 );
if ( (leds_1[row] & (1 << (7-col) )) != 0 ) {
delay(100);
}
}
}
delay(delaytime*5);
}
if (aleatorio == 6) {
//------------------------
lc.clearDisplay(1);
delay(delaytime/2);
for (int col=0;col<8;col++){
for(int row=0;row<8;row++) {
lc.setLed(1, row, col, (leds_1[row] & (1 << (7-col) )) != 0 );
if ( (leds_1[row] & (1 << (7-col) )) != 0 ) {
delay(100);
}
}
}
delay(delaytime*5);
}
if (aleatorio == 7) {
//--------------------------
lc.clearDisplay(1);
delay(delaytime/2);
for (int col=7;col>=0;col--){
for(int row=0;row<8;row++) {
lc.setLed(1, row, col, (leds_1[row] & (1 << (7-col) )) != 0 );
if ( (leds_1[row] & (1 << (7-col) )) != 0 ) {
delay(100);
}
}
}
delay(delaytime*5);
}
if (aleatorio == 8) {
//--------------------------
lc.clearDisplay(1);
delay(delaytime/2);
for(int i=0;i<64;i++) {
int r = ur.next();
int l = r / 8;
int c = r % 8;
int val = (leds_1[l] & (1 << (7-c) )) != 0 ;
if ( val ) { delay(100); }
lc.setLed(1, l, c, val );
}
ur.randomize();
delay(delaytime*5);
}
}
No Artigo anterior mostrei como gerar números aleatórios, tantos repetidos quanto não repetidos. Pra isso criei uma classe e fiz um vídeo demonstrando o uso da mesma. Para quem quiser o ver o artigo, clique aqui. Como exemplo, fiz um programa bem simples, que ligava aleatoriamente led por led de uma matriz de 8X8 e depois desligava-os um por um. Pra controlar o tempo que cada led era ligado, utilizei a função delay, ou seja, ligava um led, espera alguns milissegundos e depois ligava o próximo led.
Funcionou perfeitamente. Consegui demonstrar o que eu queria. Mas um dos problemas é que o delay utilizado dentro do laço for, me impedia de conseguir incluir uma segunda matriz de leds para fazer outra coisa. Até daria para incluir, mas seria bem trabalhoso, e se eu quisesse incluir um terceiro, quarto ou qualquer outra coisa no arduino, como um teclado, por exemplo, eu teria problemas.
for(int i=0; i<64; i++) {
int r = ur.next();
int l = r / 8;
int c = r % 8;
delay(100); //delay para cada led da matriz.
lc.setLed(0, l, c, HIGH );
}
Para solucionar esse problema, resolvi eliminar as chamadas para delay, e para isso criei uma função chamada time:
int time(long timeHigh, long timeLow, long atraso, long mref = 0) {
long ajuste = mref % (timeHigh + timeLow);
long resto = (millis() + timeHigh + timeLow - ajuste - atraso) % (timeHigh + timeLow);
return (resto < timeHigh ? HIGH : LOW);
}
Os dois primeiros parâmetros são timeHigh e timeLow. Que significa que, se por exemplo, timeHigh for 1000 e timeLow também for 1000, a função irá retornar HIGH nos primeiros 1000 milissegundos e LOW nos últimos 1000 milissegundos. Supondo que eu quisesse piscar um led no Arduino com essa função, poderia ser feito da seguinte maneira:
void loop() {
digitalWrite(13, time(1000, 1000, 0, 0) ); //pisca o led do pino 13
//colocar aqui o código para fazer outras coisas durante o pisca led
}
O terceiro parâmetro (long atraso) é usado para iniciar a contagem com um atraso de tempo, em milissegundos, enquanto que o quarto é o millis de referencia. Por exemplo, se eu quiser iniciar a contagem no momento que o usuário apertar um botão, eu passo como referência o valor lido no momento que pressionou o botão.
Para piscar 3 leds ao mesmo, mas cada um com um atraso de 300 milissegundos em relação ao anterior, poderia ser feito da seguinte maneira:
void loop() {
digitalWrite(13, time(1000, 1000, 0, 0) ); //pisca o led do pino 13
digitalWrite(12, time(1000, 1000, 300, 0) ); //pisca o led do pino 12
digitalWrite(11, time(1000, 1000, 600, 0) ); //pisca o led do pino 11
}
E ainda se eu quisesse piscar os leds apenas enquanto um botão fosse mantido pressionado, poderia ser feito da seguinte maneira:
unsigned long mref = 0;
void loop() {
if ( digitalRead(4) ) {
if (mref == 0) { mref = millis(); }
} else {
mref = 0;
}
if (mref > 0) {
digitalWrite(13, time(1000, 1000, 0, mref) ); //pisca o led do pino 13
digitalWrite(12, time(1000, 1000, 300, mref) ); //pisca o led do pino 13
digitalWrite(11, time(1000, 1000, 600, mref) ); //pisca o led do pino 13
} else {
digitalWrite(13, LOW ); //pisca o led do pino 13
digitalWrite(12, LOW ); //pisca o led do pino 13
digitalWrite(11, LOW ); //pisca o led do pino 13
}
}
Veja no vídeo abaixo a demonstração de como usar a função acima, para mostrar diferentes animações em uma matriz de leds 8x8.
Código-fonte:
#include "LedControl.h"
/**********************************************************************************
************************************CLASSE UNIQUE RANDOM***************************
**********************************************************************************/
class UniqueRandom{
private:
int _index;
int _min;
int _max;
int _size;
int* _list;
void _init(int min, int max) {
_list = 0;
if (min < max) { _min = min; _max = max; } else { _min = max; _max = min; }
_size = _max - _min;
_index = 0;
}
public:
UniqueRandom(int max) { _init(0, max); randomize(); } //construtor com 1 parametro
UniqueRandom(int min, int max) { _init(min, max); randomize(); } //construtor com 2 parametros
void randomize() {
if (_list == 0) { _list = (int*) malloc(size() * sizeof(int)); }
for (int i=0; i<size(); i++) { _list[i] = _min+i; } //preenche a lista do menor ao maior valor
//embaralha a lista
for (int i=0; i<size(); i++) {
int r = random(0, size()); //sorteia uma posição qualquer
int aux = _list[i];
_list[i] = _list[r];
_list[r] = aux;
}
}
int next() { //retorna o proximo numero da lista
int n = _list[_index++];
if (_index >= size() ) { _index = 0;} //após recuper o ultimo numero, recomeça na posicao 0
return n;
}
int size() { return _size; }
~UniqueRandom(){ free ( _list ); } //destrutor
};
/**********************************************************************************
************************************FIM CLASSE UNIQUE RANDOM***********************
**********************************************************************************/
/**********************************************************************************
************************************FUNÇÃO TIME************************************
**********************************************************************************/
int time(long timeHigh, long timeLow, long atraso, long mref = 0){
long ajuste = mref % (timeHigh + timeLow);
long resto = (millis() + timeHigh + timeLow - ajuste - atraso) % (timeHigh + timeLow);
return (resto < timeHigh ? HIGH : LOW);
}
/**********************************************************************************
************************************FIM FUNÇÃO TIME********************************
**********************************************************************************/
/*
pin 4 is connected to the DataIn
pin 6 is connected to the CLK
pin 5 is connected to LOAD
*/
LedControl lc(4,6,5, 2); //2 max7219
UniqueRandom ur(64); //declaracao do objeto unique random
unsigned long delaytime=500;
unsigned long mref0, mref1;
void setup() {
int seed = 0;
for (int i=0; i<10; i++) {
seed += ( analogRead(A0) + analogRead(A1) + analogRead(A2) + analogRead(A3) + analogRead(A4) + analogRead(A5) ) ;
delay(10);
}
randomSeed(seed);
lc.shutdown(0,false);
lc.setIntensity(0,1);
lc.clearDisplay(0);
lc.shutdown(1,false);
lc.setIntensity(1,1);
lc.clearDisplay(1);
pinMode(13, OUTPUT);
}
void loop() {
digitalWrite(13, time(1000, 1000, 0, 0) ); //pisca o led do pino 13
//display 01
long t1 = 250; //tempo entre ligar um led e outro
if ( time(1000, 64*t1*2, 0, 0) ) {
lc.clearDisplay(0);
ur.randomize();
mref0 = millis();
} else {
for(int i=0; i<64; i++) {
int r = ur.next();
int lin = r / 8;
int col = r % 8;
lc.setLed(0, lin, col, time(64*t1, 64*t1, i*t1, mref0) );
}
}
//display 02
long t2 = 700; //tempo entre ligar um led e outro
if ( time(2000, 64*t2, 0) ) {
lc.clearDisplay(1);
mref1 = millis();
} else {
for(int i=0; i<64; i++) {
int r = i;
int lin = r / 8;
int col = r % 8;
lc.setLed(1, lin, col, time(64*t2, 64*t2, i*t2, mref1) );
}
}
}
segundo-exemplo:
unsigned long mref1=-10000;
unsigned long mref2=-10000;
int t1 = 1000; //tempo 1
int t2 = 4000; //tempo 2
/*
A FUNÇÃO TIME ESTÁ ESPLICADA NESSE LINK:
http://fabianoallex.blogspot.com.br/2015/09/arduino-como-substituir-delay-pelo.html
*/
int time(long timeHigh, long timeLow, long atraso, long mref = 0) {
long ajuste = mref % (timeHigh + timeLow);
long resto = (millis() + timeHigh + timeLow - ajuste - atraso) % (timeHigh + timeLow);
return (resto < timeHigh ? HIGH : LOW);
}
void setup() {
pinMode(3, OUTPUT); //led
pinMode(4, OUTPUT); //led
pinMode(8, INPUT); //botao
pinMode(9, INPUT); //botao
}
// the loop routine runs over and over again forever:
void loop() {
if (digitalRead(8) && (millis()-mref1) > t1 ){ mref1 = millis(); }
if (digitalRead(9) && (millis()-mref2) > t2 ){ mref2 = millis(); }
if ( (millis()-mref1) <= t1 && (mref1 > 0) ) { digitalWrite(3, time(200,200,0,mref1) ); } else { digitalWrite(3, LOW); }
if ( (millis()-mref2) <= t2 && (mref2 > 0) ) { digitalWrite(4, time(200,200,0,mref2) ); } else { digitalWrite(4, LOW); }
delay(10);
}
Atualização - 21/10/2015
O Vídeo abaixo mostra alguns outros detalhes a ser considerado na hora de trabalhar com temporização no Arduino, pra isso criei uma classe chamada MyTimer, que detecta tanto se tá em timeHigh, timeLow, borda de subida e borda de descida, o que dá mais possibilidades na hora de trabalhar com temporização.
A classe mostrada acima (MyTimer) foi modificada para executar funções de callback. Pra isso fiz um vídeo falando sobre o assunto (ponteiro pra funções e funções de callback). Mais abaixo está o código alterado.
Mais uma atualização no artigo, agora iremos controlar uma quantidade indefinida de eventos que devem ser executados cada um por um determinado intervalo de tempo. Pra isso criei uma nova versão da classe MyTimer.
vídeo:
/*********************************************************************************************************
************************************CLASSE MYTIMER********************************************************
**********************************************************************************************************/
class MyTimer{
private:
unsigned long _mref;
unsigned long *_times;
long _lag;
unsigned int _quantidade;
int _index_time;
int _last_index_time;
void (*_onChanging)( int index_time ); //ponteiro para funcao do evento
public:
MyTimer(unsigned long times[], int quantidade, long lag, unsigned long mref){
_lag = lag;
_mref = mref;
_times = times;
_quantidade = quantidade;
_undetermine();
}
void _undetermine(){
_index_time = -1;
_last_index_time = -1;
update();
}
void setTimes(unsigned long times[], int quantidade){
_times = times;
_quantidade = quantidade;
_undetermine();
update();
};
void setMillisRef(unsigned long mref) { _mref = mref; _undetermine(); }
void setLag(long lag) { _lag = lag; _undetermine(); }
boolean isChanging() { return ( _index_time != _last_index_time); }
boolean isIndexTime(int index) { return ( _index_time == index); }
void setOnChanging( void (*onChanging)(int) ) { _onChanging = onChanging; }
void update();
};
void MyTimer::update(){
unsigned long s = 0;
for (int i=0; i<_quantidade;i++){ s += _times[i]; }
long adjustment = _mref % s;
long rest = (millis() + s - adjustment - _lag) % s;
_last_index_time = _index_time;
s = 0;
for (int i=0; i<_quantidade;i++){
s += _times[i];
if (rest < s) { _index_time = i; break; }
}
if ( isChanging() && _onChanging ) { (*_onChanging)( _index_time ); }
}
/*********************************************************************************************************
************************************FIM CLASSE MYTIMER****************************************************
**********************************************************************************************************/
//vermelho 800 milissegundos
//amarelo 200 milissegundos
//azul 500 milissegundos
//amarelo 200 milissegundos
//verde 300 milissegundos
//amarelo 200 milissegundos
unsigned long times[] = {800, 200, 500, 200, 300, 200};
MyTimer t1(times, sizeof(times)/sizeof(unsigned long), 100, 0); //tem um atraso de 100 milissegundos em relação a referencia 0
MyTimer t2(times, sizeof(times)/sizeof(unsigned long), 300, 0); //tem um atraso de 300 milissegundos em relação a referencia 0
void setup() {
Serial.begin(9600);
t1.setOnChanging( onChanging_t1 );
t2.setOnChanging( onChanging_t2 );
pinMode(8, OUTPUT);
pinMode(9, OUTPUT);
pinMode(10, OUTPUT);
pinMode(5, OUTPUT);
pinMode(6, OUTPUT);
pinMode(7, OUTPUT);
}
void loop() {
t1.update();
t2.update();
}
void onChanging_t1(int index ) {
if (index == 0 ){ digitalWrite(8, HIGH); digitalWrite(9, LOW); digitalWrite(10, LOW); }
if (index == 2) { digitalWrite(8, LOW); digitalWrite(9, HIGH); digitalWrite(10, LOW); }
if (index == 4) { digitalWrite(8, LOW); digitalWrite(9, LOW); digitalWrite(10, HIGH); }
if (index == 1 || index == 3 || index == 5){ digitalWrite(8, HIGH); digitalWrite(9, LOW); digitalWrite(10, HIGH); }
}
void onChanging_t2(int index ) {
if (index == 0 ){ digitalWrite(5, HIGH); digitalWrite(6, LOW); digitalWrite(7, LOW); }
if (index == 2) { digitalWrite(5, LOW); digitalWrite(6, HIGH); digitalWrite(7, LOW); }
if (index == 4) { digitalWrite(5, LOW); digitalWrite(6, LOW); digitalWrite(7, HIGH); }
if (index == 1 || index == 3 || index == 5){ digitalWrite(5, HIGH); digitalWrite(6, LOW); digitalWrite(7, HIGH); }
}
Atualização 13/12/2015
No início desse artigo mostrei uma função chamada time, bem simples, que recriei agora de modo que de pra ser executado algo a cada tantos millissegundos. Segue o código:
boolean time(unsigned long * mref, unsigned long t){
if (millis() > t && millis() - *mref > t){ *mref = millis(); return true; }
return false;
}
void setup() {
Serial.begin(9600) ;
}
void loop() {
static unsigned long mref1=0; //millis de referencia. inicializado em 0
if (time(&mref1, 2000)){
Serial.print("1-");
Serial.println(millis());
}
static unsigned long mref2=300; //millis de referencia. inicializado em 300
if (time(&mref2, 1800)){
Serial.print("2-");
Serial.println(millis());
}
}
No Arduino temos duas funções que nos permitem gerar números aleatórios.
RandomSeed() e Random().
Na verdade os números aleatórios gerados em conjunto pelas funções acimas não são inteiramente aleatórios, eles são na verdade pseudo aleatórios, o que significa dizer, que parecem números aleatórios, mas não são. Na prática, os números aleatórios gerados pelas funções acima, são pré determinados, dependendo do valor passado para RandomSeed(valor).
Normalmente RandomSeed é chamado no início da execução do programa e inicializado com um valor qualquer, porém se na inicialização de RandomSeed for passado sempre o mesmo valor, a sequencia de números aleatórios gerados será sempre a mesma.
Se a intenção for gerar sequencia de números diferentes a cada inicialização de randomSeed, deve-se então, ser passado valores diferentes a cada inicialização.
Existem algumas alternativas no Arduino para conseguirmos números (seed: que significa semente) diferentes a cada vez que se deseja inicializar o RandomSeed. A mais utilizada é utilizar o valor lido de uma porta analógica não conectada, que por não estar conectada, acaba retornando valores diferentes. Nos casos em que os números aleatórios são gerados a partir de uma ação externa do arduino, como o pressionar de um botão, a leitura de um valor ou qualquer outra ação, o valor a ser utilizado para inicializar o RandomSeed, pode ser baseado no valor de millis() do arduino, que é o tempo em millissegundos já passados desde que o arduino foi ligado. Outra possibilidade seria ainda gravar na eeprom o ultimo utilizado para inicializar, e na próxima vez que o arduino inicializar o RandomSeed, o valor gravado na eeprom ser incrementado.
Como vimos, então, randomSeed é utilizado para gerar uma sequencia aleatória de números. Agora vamos ver como funciona a função random(), que é a função que retorna o número aleatório, quando desejamos um.
random() pode ser chamada com dois, ou com um parâmetros. Quando chamada com dois, significa que queremos números aleatórios entre o primeiro e o ultimo valor, por exemplo, random(10, 20) irá retornar somentes os seguintes valores {10,11,12,13,14,15,16,17,18 e 19}. Percebam que 20 não será retornado.
Quando chamada com um único parâmetro, como por exemplo, random(300), significa que irá retornar qualquer valor entre 0 e 299.
abaixo tem um exemplo retirado da página do Arduino:
long randNumber;
void setup() {
Serial.begin(9600);
// if analog input pin 0 is unconnected, random analog
// noise will cause the call to randomSeed() to generate
// different seed numbers each time the sketch runs.
// randomSeed() will then shuffle the random function.
randomSeed(analogRead(0));
}
void loop() {
// print a random number from 0 to 299
randNumber = random(300);
Serial.println(randNumber);
// print a random number from 10 to 19
randNumber = random(10, 20);
Serial.println(randNumber);
delay(50);
}
Aleatórios não repetidos
Quando projetamos um programa que necessita de valores aleatórios, há basicamente duas situações diferentes, que são os casos onde os números sorteados podem se repetir, e outras onde os números não podem se repetir.
Num bingo por exemplo, os números sorteados nunca se repetem, pois a cada valor sorteado o mesmo é removido do globo, enquanto que numa roleta de cassino os valores sorteados podem ser repetidos.
Para conseguirmos gerar números não repetidos, é necessário gerarmos uma lista de números, embaralharmos os mesmos (muda-los de posição de modo aleatório), e posteriormente lermos os números sequencialmente do início da lista até o fim. Assim garantimos que se tenhamos 10 números na lista não iremos ter sorteios repetidos nos primeiros 10 números sorteados.
Para facilitar esse processo, criei uma classe que faz esse trabalho.
/**********************************************************************************
************************************CLASSE UNIQUE RANDOM***************************
**********************************************************************************/
class UniqueRandom{
private:
int _index;
int _min;
int _max;
int _size;
int* _list;
void _init(int min, int max) {
_list = 0;
if (min < max) { _min = min; _max = max; } else { _min = max; _max = min; }
_size = _max - _min;
_index = 0;
}
public:
UniqueRandom(int max) { _init(0, max); randomize(); } //construtor com 1 parametro
UniqueRandom(int min, int max) { _init(min, max); randomize(); } //construtor com 2 parametros
void randomize() {
if (_list == 0) { _list = (int*) malloc(size() * sizeof(int)); }
for (int i=0; i<size(); i++) { _list[i] = _min+i; } //preenche a lista do menor ao maior valor
//embaralha a lista
for (int i=0; i<size(); i++) {
int r = random(0, size()); //sorteia uma posição qualquer
int aux = _list[i];
_list[i] = _list[r];
_list[r] = aux;
}
}
int next() { //retorna o proximo numero da lista
int n = _list[_index++];
if (_index >= size() ) { _index = 0;} //após recuper o ultimo numero, recomeça na posicao 0
return n;
}
int size() { return _size; }
~UniqueRandom(){ free ( _list ); } //destrutor
};
/**********************************************************************************
************************************FIM CLASSE UNIQUE RANDOM***********************
**********************************************************************************/
/**********************************************************************************
************************************SETUP / LOOP***********************************
**********************************************************************************/
UniqueRandom ur(10, 30); //declaracao do objeto unique random
void setup() {
Serial.begin(9600);
int seed = 0;
for (int i=0; i<10; i++) {
seed += ( analogRead(A0) + analogRead(A1) + analogRead(A2) + analogRead(A3) + analogRead(A4) + analogRead(A5) ) ;
delay(10);
}
randomSeed(seed);
Serial.print("Seed: ");
Serial.println(seed);
}
void loop() {
Serial.println("");
Serial.print( "Iniciando com " );
Serial.print( ur.size() );
Serial.print( " itens: " );
ur.randomize(); //gera os numeros aleatoriamente
for (int i=0; i<ur.size(); i++){
Serial.print( ur.next() );
Serial.print( " " );
}
delay(100);
}
/**********************************************************************************
************************************FIM SETUP / LOOP*******************************
**********************************************************************************/
Exemplo de uso com matriz de led 8x8
#include "LedControl.h"
/**********************************************************************************
************************************CLASSE UNIQUE RANDOM***************************
**********************************************************************************/
class UniqueRandom{
private:
int _index;
int _min;
int _max;
int _size;
int* _list;
void _init(int min, int max) {
_list = 0;
if (min < max) { _min = min; _max = max; } else { _min = max; _max = min; }
_size = _max - _min;
_index = 0;
}
public:
UniqueRandom(int max) { _init(0, max); randomize(); } //construtor com 1 parametro
UniqueRandom(int min, int max) { _init(min, max); randomize(); } //construtor com 2 parametros
void randomize() {
if (_list == 0) { _list = (int*) malloc(size() * sizeof(int)); }
for (int i=0; i<size(); i++) { _list[i] = _min+i; } //preenche a lista do menor ao maior valor
//embaralha a lista
for (int i=0; i<size(); i++) {
int r = random(0, size()); //sorteia uma posição qualquer
int aux = _list[i];
_list[i] = _list[r];
_list[r] = aux;
}
}
int next() { //retorna o proximo numero da lista
int n = _list[_index++];
if (_index >= size() ) { _index = 0;} //após recuper o ultimo numero, recomeça na posicao 0
return n;
}
int size() { return _size; }
~UniqueRandom(){ free ( _list ); } //destrutor
};
/**********************************************************************************
************************************FIM CLASSE UNIQUE RANDOM***********************
**********************************************************************************/
/*
pin 4 is connected to the DataIn
pin 6 is connected to the CLK
pin 5 is connected to LOAD
*/
LedControl lc=LedControl(4,6,5,1); //1 max7219
UniqueRandom ur(64); //declaracao do objeto unique random
/* we always wait a bit between updates of the display */
unsigned long delaytime=500;
void setup() {
int seed = 0;
for (int i=0; i<10; i++) {
seed += ( analogRead(A0) + analogRead(A1) + analogRead(A2) + analogRead(A3) + analogRead(A4) + analogRead(A5) ) ;
delay(10);
}
randomSeed(seed);
lc.shutdown(0,false);
lc.setIntensity(0,8);
lc.clearDisplay(0);
}
void loop() {
lc.clearDisplay(0);
delay(delaytime/2);
ur.randomize();
for(int i=0; i<64; i++) {
int r = ur.next();
int l = r / 8;
int c = r % 8;
delay(100);
lc.setLed(0, l, c, HIGH );
}
ur.randomize();
for(int i=0; i<64; i++) {
int r = ur.next();
int l = r / 8;
int c = r % 8;
delay(100);
lc.setLed(0, l, c, LOW );
}
delay(delaytime*2);
}
Atualização 25/11/2015 - Números do tipo double ou float (com casas decimais)
Essa semana me pediram como fazer para gerar números aleatórios com números números do tipo double ou float, ou seja, com casas decimais. Na verdade a ideia é até bem simples, vamos supor que você queira números aleatórios entre 5.58 e 9.44... considerando os números com até duas casas decimais nesse intervalo.
Nesse caso basta multiplicar o 5.58 por 100 (ou 10² ou pow(10, 2) ) o que daria um número inteiro igual a 558. Aplicando o mesmo ao 9.44 teremos 944. Se fosse com 3 casas decimais, multiplicaríamos o número por 1000 (ou 10³ ou pow(10,3) ).
Tendo convertido os dois números para inteiros, bastaria agora utilizar a função random normalmente, porém o valor retornado precisa ser divido pelo valor multiplicado anteriormente para que o mesmo volte à mesma faixa utilizada inicialmente, tendo o cuidado de armazenar o resultado em um campo do tipo double, para que as casas decimais não sejam perdidas.
Para facilitar o uso, criei um exemplo com uma função que chamei de randomDouble, onde são passados 3 valores: o valor mínimo, o valor máximo, e a quantidade de casas decimais a ser considerada:
Código:
double randomDouble(double min, double max, int numCasas){
long _min = min * pow(10, numCasas) + 0.1; //0.1--> para corrigir erro da funcao pow. funciona até 4 casas. mais que isso da erro no calculo.
long _max = max * pow(10, numCasas) + 0.1;
return (double) random(_min, _max) / pow(10, numCasas) ;
}
void setup() {
Serial.begin(9600);
randomSeed(analogRead(0));
}
void loop() {
double randNumber = randomDouble(10.20, 11.05, 2);
Serial.println(randNumber);
delay(500);
}
